# Copyright 2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=setuptools
DISTUTILS_SINGLE_IMPL=1
PYTHON_COMPAT=( python3_{12..13} )

inherit distutils-r1

DESCRIPTION="Ultra-lightweight text-to-speech model"
HOMEPAGE="https://github.com/KittenML/KittenTTS https://pypi.org/project/kittentts/"
SRC_URI="https://github.com/KittenML/KittenTTS/archive/refs/tags/${PV}.tar.gz -> ${P}.gh.tar.gz"
S="${WORKDIR}/KittenTTS-${PV}"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64"
RESTRICT="test"

PATCHES=(
	"${FILESDIR}"/${P}-drop-unused-misaki-import.patch
)

RDEPEND="
	sci-ml/huggingface_hub[${PYTHON_SINGLE_USEDEP}]
	$(python_gen_cond_dep '
		dev-python/num2words[${PYTHON_USEDEP}]
		dev-python/numpy[${PYTHON_USEDEP}]
		dev-python/phonemizer-fork[${PYTHON_USEDEP}]
		dev-python/soundfile[${PYTHON_USEDEP}]
		sci-libs/onnxruntime[python,${PYTHON_USEDEP}]
	')
"
DEPEND="${RDEPEND}"

pkg_postinst() {
	elog "KittenTTS downloads model files from Hugging Face at runtime."
}