# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

CMAKE_BUILD_TYPE="Release"
MY_PN="${PN/intel-/}"
MY_P="${MY_PN}-${PV}"

inherit cmake flag-o-matic

DESCRIPTION="Intel Graphics Compute Runtime for oneAPI Level Zero and OpenCL Driver"
HOMEPAGE="https://github.com/intel/compute-runtime"
SRC_URI="https://github.com/intel/${MY_PN}/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/${MY_P}"

LICENSE="MIT"
SLOT="0/1.6.$(ver_cut 3)"
KEYWORDS="~amd64"
IUSE="disable-mitigations +l0 intel_targets_gfx-bmg +vaapi test"
RESTRICT="!test? ( test )"

RDEPEND="
	!dev-libs/intel-compute-runtime:legacy
	>=dev-util/intel-graphics-compiler-2.32.7:0
	!dev-util/intel-graphics-compiler:legacy
	>=media-libs/gmmlib-22.7.1:=
"

DEPEND="
	${RDEPEND}
	dev-libs/intel-metrics-discovery:=
	>=dev-libs/intel-metrics-library-1.0.200:=
	dev-libs/libnl:3
	dev-libs/libxml2:2
	>=dev-util/intel-graphics-system-controller-0.9.6:=
	media-libs/mesa
	>=virtual/opencl-3
	l0? ( >=dev-libs/level-zero-1.24.2:= )
	vaapi? (
		x11-libs/libdrm[video_cards_intel]
		media-libs/libva
	)
"

BDEPEND="virtual/pkgconfig"

DOCS=( "README.md" "FAQ.md" )

PATCHES=(
	"${FILESDIR}/25.40.9999-${PN}-test.patch"
	"${FILESDIR}/${PV}-${PN}-opencl-kernel-vector-helpers.patch"
	"${FILESDIR}/${PV}-${PN}-llvm22-cxx-types.patch"
	"${FILESDIR}/${PV}-${PN}-llvm22-test-kernels.patch"
	"${FILESDIR}/${PV}-${PN}-pool-buffer-context-ref.patch"
)

src_prepare() {
	# Remove '-Werror' from default
	sed -e '/Werror/d' -i CMakeLists.txt || die

	cmake_src_prepare
}

src_configure() {
	filter-lto

	local mycmakeargs=(
		-DCCACHE_ALLOWED="OFF"
		-DCMAKE_INSTALL_PREFIX="${EPREFIX}/usr"
		-DCMAKE_INSTALL_LIBDIR="$(get_libdir)"
		-DBUILD_WITH_L0="$(usex l0)"
		-DDISABLE_LIBVA="$(usex !vaapi)"
		-DNEO_ALLOW_LEGACY_PLATFORMS_SUPPORT="ON"
		-DNEO_DISABLE_LTO="ON"
		-DNEO_DISABLE_MITIGATIONS="$(usex disable-mitigations)"
		-DNEO_BUILD_UNVERSIONED_OCLOC="ON"
		-DNEO__METRICS_LIBRARY_INCLUDE_DIR="${ESYSROOT}/usr/include"
		-DKHRONOS_GL_HEADERS_DIR="${ESYSROOT}/usr/include"
		-DOCL_ICD_VENDORDIR="${EPREFIX}/etc/OpenCL/vendors"
		-Wno-dev
		-DSKIP_UNIT_TESTS="$(usex !test)"
	)

	if use intel_targets_gfx-bmg; then
		mycmakeargs+=(
			-DSUPPORT_GEN_DEFAULT="OFF"
			-DSUPPORT_PLATFORM_DEFAULT="OFF"
			-DSUPPORT_BMG="ON"
			-DDEFAULT_SUPPORTED_PLATFORM="BMG"
		)
		if use test; then
			mycmakeargs+=(
				-DTESTS_BMG="ON"
				-DDEFAULT_TESTED_PLATFORM="BMG"
			)
		fi
	else
		mycmakeargs+=( -DSUPPORT_DG1="ON" )
	fi

	cmake_src_configure
}

src_test() {
	addpredict /
	cmake_build run_unit_tests
}