diff --git a/app-admin/bitwarden-desktop-bin/Manifest b/app-admin/bitwarden-desktop-bin/Manifest
new file mode 100644
index 0000000..2eafdca
--- /dev/null
+++ b/app-admin/bitwarden-desktop-bin/Manifest
@@ -0,0 +1 @@
+DIST Bitwarden-2025.10.0-amd64.deb 90362570 BLAKE2B 7a6eff1b049dd1d26c1864ffb2cf54b5cec45a84e57835bed0346bac10a68f373bc2ef8d9a3a59560693b6845ffaaa680b63bf1e3db2857b6374fe9208c65d7d SHA512 c58ce9edeb9caae8435460e34f2a2e2f48d66d98290b4d5636ecf7bc02143d0828674940b85684dbe0081fae5013fb248043309555c9da458df640c52cabf356
diff --git a/app-admin/bitwarden-desktop-bin/bitwarden-desktop-bin-2025.10.0.ebuild b/app-admin/bitwarden-desktop-bin/bitwarden-desktop-bin-2025.10.0.ebuild
new file mode 100644
index 0000000..0255d8a
--- /dev/null
+++ b/app-admin/bitwarden-desktop-bin/bitwarden-desktop-bin-2025.10.0.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit desktop unpacker xdg-utils
+
+DESCRIPTION="Bitwarden password manager desktop client"
+HOMEPAGE="https://bitwarden.com/"
+SRC_URI="https://github.com/bitwarden/clients/releases/download/desktop-v${PV}/Bitwarden-${PV}-amd64.deb"
+S="${WORKDIR}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	app-crypt/libsecret
+	dev-libs/expat
+	dev-libs/glib
+	dev-libs/nspr
+	dev-libs/nss
+	dev-libs/wayland
+	media-libs/alsa-lib
+	media-libs/mesa
+	net-print/cups
+	sys-apps/dbus
+	sys-apps/util-linux
+	sys-libs/glibc
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libX11
+	x11-libs/libxcb
+	x11-libs/libXcomposite
+	x11-libs/libXcursor
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libxkbcommon
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/libXScrnSaver
+	x11-libs/libxshmfence
+	x11-libs/libXtst
+	x11-libs/pango
+"
+IDEPEND="
+	dev-util/desktop-file-utils
+	dev-util/gtk-update-icon-cache
+"
+
+QA_PREBUILT="
+	opt/Bitwarden/*.so*
+	opt/Bitwarden/bitwarden
+	opt/Bitwarden/bitwarden-app
+	opt/Bitwarden/chrome-sandbox
+	opt/Bitwarden/chrome_crashpad_handler
+	opt/Bitwarden/desktop_proxy
+"
+
+src_install() {
+	insinto /opt
+	doins -r opt/Bitwarden
+	fperms 755 /opt/Bitwarden/bitwarden \
+		/opt/Bitwarden/bitwarden-app
+	fperms 4755 /opt/Bitwarden/chrome-sandbox
+
+	domenu usr/share/applications/bitwarden.desktop
+
+	local x
+	for x in 16 32 64 128 256 512; do
+		doicon -s ${x} usr/share/icons/hicolor/${x}*/*
+	done
+
+	dosym -r "/opt/Bitwarden/bitwarden" "usr/bin/${PN}"
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
diff --git a/app-admin/bitwarden-desktop-bin/metadata.xml b/app-admin/bitwarden-desktop-bin/metadata.xml
new file mode 100644
index 0000000..4f19290
--- /dev/null
+++ b/app-admin/bitwarden-desktop-bin/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>dlan@gentoo.org</email>
+		<name>Yixun Lan</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">bitwarden/desktop</remote-id>
+	</upstream>
+</pkgmetadata>