Initial simplex-desktop package based off deb package

dev-cpp/cppgir/Manifest

@@ -0,0 +1 @@
+DIST cppgir-0_p20240102.tar.bz2 102421 BLAKE2B f0b1ac871e7fc662c5c2aeb24cb8cb4f8570ae832f4ac6afdadb3c811f4ebc91862f8571133dfb9314fa994449b4d7cc4344f7a8a2aabcaa395d793bc4ca3655 SHA512 67778c6dec24a9afd848241c768af9fd3c9098e00ba168ebe5d776f3b5086b2489c38247a6441c99f7971dd53315e2758fe38c21fced44d857dc064e66f50731

dev-cpp/cppgir/cppgir-0_p20240102.ebuild

@@ -0,0 +1,46 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="GObject-Introspection C++ binding wrapper generator"
+HOMEPAGE="https://gitlab.com/mnauw/cppgir"
+
+MY_PV="4c16bffe646af52b7112785cda8112d761f95860"
+SRC_URI="https://gitlab.com/mnauw/cppgir/-/archive/${MY_PV}/cppgir-${MY_PV}.tar.bz2 -> ${P}.tar.bz2"
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~loong ~riscv"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/boost:=
+	dev-libs/libfmt:=
+"
+DEPEND="${RDEPEND}
+	dev-cpp/expected-lite
+"
+BDEPEND="
+	doc? ( app-text/ronn-ng )
+	test? ( dev-libs/glib )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_DOC=$(usex doc)
+		-DBUILD_TESTING=$(usex test)
+		-DBUILD_EXAMPLES=no
+		-DINTERNAL_EXPECTED=no
+	)
+
+	append-cppflags \
+		-UDEFAULT_GIRPATH \
+		-DDEFAULT_GIRPATH="${EPREFIX}/usr/share:${EPREFIX}/usr/local/share"
+
+	cmake_src_configure
+}

dev-cpp/cppgir/metadata.xml

@@ -0,0 +1,16 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person" proxied="yes">
+    <email>esteve.varela@gmail.com</email>
+    <name>Esteve Varela Colominas</name>
+  </maintainer>
+  <maintainer type="project" proxied="proxy">
+    <email>proxy-maint@gentoo.org</email>
+    <name>Proxy Maintainers</name>
+  </maintainer>
+  <upstream>
+    <remote-id type="gitlab">mnauw/cppgir</remote-id>
+    <bugs-to>https://gitlab.com/mnauw/cppgir/-/issues</bugs-to>
+  </upstream>
+</pkgmetadata>