Initial simplex-desktop package based off deb package

app-forensics/maltego/maltego-4.2.18.13878.ebuild

@@ -0,0 +1,62 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop eutils unpacker xdg-utils
+
+DESCRIPTION="Visualise, map and mine data"
+HOMEPAGE="https://www.paterva.com/"
+
+SHORT_V="$(ver_cut 1-3)"
+SRC_URI="https://www.paterva.com/malv${SHORT_V//./}/Maltego.v${PV}.deb -> ${P}.deb"
+#SRC_URI="https://maltego-downloads.s3.us-east-2.amazonaws.com/linux/Maltego.v${PV}.deb -> ${P}.deb"
+
+KEYWORDS="~amd64 ~x86"
+LICENSE="Paterva-EULA"
+SLOT=0
+IUSE=""
+
+DEPEND="$(unpacker_src_uri_depends)"
+RDEPEND="virtual/jre"
+
+S="${WORKDIR}"
+
+src_prepare() {
+	# Cleanup
+	rm -fr usr/{share/doc,share/applications,bin} || die
+	default
+}
+
+src_install() {
+	doins -r *
+
+	fperms +x "/usr/share/${PN}/bin/${PN}"
+	dosym "../share/${PN}/bin/${PN}" "/usr/bin/${PN}"
+
+	make_wrapper \
+		"${PN}_memory_config" \
+		"/usr/bin/java -jar \"/usr/share/maltego/maltego-ui/modules/ext/Java_Config_App.jar\""
+
+	make_desktop_entry \
+		"${PN}" \
+		"Maltego" \
+		"${PN}" \
+		"Development;Utility;"
+
+	make_desktop_entry \
+		"${PN}_memory_config" \
+		"Maltego Memory Config" \
+		"${PN}" \
+		"Settings;"
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}