mirror of
https://github.com/curl/curl.git
synced 2026-04-29 17:22:13 +03:00
b39c158e4a
Fix SC2046: "Quote this to prevent word splitting." Ref: https://www.shellcheck.net/wiki/SC2046 Also: - shellcheck.sh: add `set -eu`. - shellcheck.sh, yamlcheck.sh: always run from repo root. - pass `--` before passing the list of files, where missing. - badwords.pl, cleancmd.pl: rework to accept `git ls-files` arguments. Requires Perl 5.22+ (2015-Jun-01) on Windows. Ref: https://perldoc.perl.org/functions/open - INTERNALS.md: require Perl 5.22 on Windows. - spacecheck.pl: formatting. - GHA/http3-linux: rework command to avoid SC2046. - stop suppressing SC2046 warnings. The yamlcheck.sh issue reported-by: Stanislav Fort (Aisle Research) Ref: 20251109163515_6eb31da3-deb2-4f4d-8327-935904f27da5 Closes #19432
89 lines
2.1 KiB
Perl
Executable file
89 lines
2.1 KiB
Perl
Executable file
#!/usr/bin/env perl
|
|
# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
|
|
#
|
|
# SPDX-License-Identifier: curl
|
|
#
|
|
# bad[:=]correct
|
|
#
|
|
# If separator is '=', the string will be compared case sensitively.
|
|
# If separator is ':', the check is done case insensitively.
|
|
#
|
|
# To add white listed uses of bad words that are removed before checking for
|
|
# the bad ones:
|
|
#
|
|
# ---(accepted word)
|
|
#
|
|
|
|
use strict;
|
|
use warnings;
|
|
|
|
my @whitelist;
|
|
my %alt;
|
|
my %exactcase;
|
|
|
|
my @w;
|
|
while(<STDIN>) {
|
|
chomp;
|
|
if($_ =~ /^#/) {
|
|
next;
|
|
}
|
|
if($_ =~ /^---(.*)/) {
|
|
push @whitelist, $1;
|
|
}
|
|
elsif($_ =~ /^([^:=]*)([:=])(.*)/) {
|
|
my ($bad, $sep, $better)=($1, $2, $3);
|
|
push @w, $bad;
|
|
$alt{$bad} = $better;
|
|
if($sep eq "=") {
|
|
$exactcase{$bad} = 1;
|
|
}
|
|
}
|
|
}
|
|
|
|
my $errors = 0;
|
|
|
|
sub file {
|
|
my ($f) = @_;
|
|
my $l = 0;
|
|
open(F, "<$f");
|
|
while(<F>) {
|
|
my $in = $_;
|
|
$l++;
|
|
chomp $in;
|
|
if($in =~ /^ /) {
|
|
next;
|
|
}
|
|
# remove the link part
|
|
$in =~ s/(\[.*\])\(.*\)/$1/g;
|
|
# remove backticked texts
|
|
$in =~ s/\`.*\`//g;
|
|
# remove whitelisted patterns
|
|
for my $p (@whitelist) {
|
|
$in =~ s/$p//g;
|
|
}
|
|
foreach my $w (@w) {
|
|
my $case = $exactcase{$w};
|
|
if(($in =~ /^(.*)$w/i && !$case) ||
|
|
($in =~ /^(.*)$w/ && $case) ) {
|
|
my $p = $1;
|
|
my $c = length($p)+1;
|
|
print STDERR "$f:$l:$c: error: found bad word \"$w\"\n";
|
|
printf STDERR " %4d | $in\n", $l;
|
|
printf STDERR " | %*s^%s\n", length($p), " ",
|
|
"~" x (length($w)-1);
|
|
printf STDERR " maybe use \"%s\" instead?\n", $alt{$w};
|
|
$errors++;
|
|
}
|
|
}
|
|
}
|
|
close(F);
|
|
}
|
|
|
|
my @filemasks = @ARGV;
|
|
open(my $git_ls_files, '-|', 'git', 'ls-files', '--', @filemasks) or die "Failed running git ls-files: $!";
|
|
while(my $each = <$git_ls_files>) {
|
|
chomp $each;
|
|
file($each);
|
|
}
|
|
close $git_ls_files;
|
|
exit $errors;
|