mirror of
https://github.com/curl/curl.git
synced 2026-07-09 15:47:15 +03:00
8e34505776
- reduce `check_include_file_concat()` use to those headers that either
depend on a previously detected header, or another header or symbol
detection depend on it.
- replace `check_symbol_exists()` with `check_function_exists()` for
functions that are detected with `AC_CHECK_FUNCS()` in `./configure`.
This makes `setmode()` no longer be detected with MSYS, syncing
this with `./configure`. Instead `_setmode()` is used now also in
CMake MSYS builds. This is consistent with Cygwin builds also.
- add comment about which header/symbol detection depends on what
header. Based on `./configure` mainly.
- form `CURL_TEST_DEFINES` manually, and include only those macros which
are actually used in `CMake/CurlTests.c`.
- change `curl_internal_test()` to use `CMAKE_REQUIRED_DEFINITIONS`,
instead of `CMAKE_REQUIRED_FLAGS` to simplify the logic, and to allow
dropping the latter macro completely.
- drop `windows.h` from header and symbol checks.
- `./configure`: add comment about whether `netinet/in6.h`, `sys/un.h`
are indeed meant to be included for all detections. There is a chance
they were added there by accident.
Detection resuls were cross-checked between
436bbbe7ab (master) and
48ff4694e608ccfdedf7ce5bab2b96d6b2c23cda (this PR), for CI GHA Linux,
Linux HTTP/3, non-native, macOS and Windows jobs.
Closes #15164
83 lines
3.2 KiB
CMake
83 lines
3.2 KiB
CMake
#***************************************************************************
|
|
# _ _ ____ _
|
|
# Project ___| | | | _ \| |
|
|
# / __| | | | |_) | |
|
|
# | (__| |_| | _ <| |___
|
|
# \___|\___/|_| \_\_____|
|
|
#
|
|
# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
|
|
#
|
|
# This software is licensed as described in the file COPYING, which
|
|
# you should have received as part of this distribution. The terms
|
|
# are also available at https://curl.se/docs/copyright.html.
|
|
#
|
|
# You may opt to use, copy, modify, merge, publish, distribute and/or sell
|
|
# copies of the Software, and permit persons to whom the Software is
|
|
# furnished to do so, under the terms of the COPYING file.
|
|
#
|
|
# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
|
|
# KIND, either express or implied.
|
|
#
|
|
# SPDX-License-Identifier: curl
|
|
#
|
|
###########################################################################
|
|
# File defines convenience macros for available feature testing
|
|
|
|
# Check if header file exists and add it to the list.
|
|
# This macro is intended to be called multiple times with a sequence of
|
|
# possibly dependent header files. Some headers depend on others to be
|
|
# compiled correctly.
|
|
macro(check_include_file_concat _file _variable)
|
|
check_include_files("${CURL_INCLUDES};${_file}" ${_variable})
|
|
if(${_variable})
|
|
set(CURL_INCLUDES ${CURL_INCLUDES} ${_file})
|
|
endif()
|
|
endmacro()
|
|
|
|
# For other curl specific tests, use this macro.
|
|
# Return result in variable: CURL_TEST_OUTPUT
|
|
macro(curl_internal_test _curl_test)
|
|
if(NOT DEFINED "${_curl_test}")
|
|
string(REPLACE ";" " " _cmake_required_definitions "${CMAKE_REQUIRED_DEFINITIONS}")
|
|
if(CMAKE_REQUIRED_LIBRARIES)
|
|
set(_curl_test_add_libraries
|
|
"-DLINK_LIBRARIES:STRING=${CMAKE_REQUIRED_LIBRARIES}")
|
|
endif()
|
|
|
|
message(STATUS "Performing Test ${_curl_test}")
|
|
try_compile(${_curl_test}
|
|
${CMAKE_BINARY_DIR}
|
|
"${CMAKE_CURRENT_SOURCE_DIR}/CMake/CurlTests.c"
|
|
CMAKE_FLAGS
|
|
"-DCOMPILE_DEFINITIONS:STRING=-D${_curl_test} ${CURL_TEST_DEFINES} ${_cmake_required_definitions}"
|
|
"${_curl_test_add_libraries}"
|
|
OUTPUT_VARIABLE CURL_TEST_OUTPUT)
|
|
if(${_curl_test})
|
|
set(${_curl_test} 1 CACHE INTERNAL "Curl test")
|
|
message(STATUS "Performing Test ${_curl_test} - Success")
|
|
else()
|
|
set(${_curl_test} "" CACHE INTERNAL "Curl test")
|
|
message(STATUS "Performing Test ${_curl_test} - Failed")
|
|
endif()
|
|
endif()
|
|
endmacro()
|
|
|
|
macro(curl_dependency_option _dependency)
|
|
set(CURL_${_dependency} "AUTO" CACHE STRING "Build curl with ${_dependency} support (AUTO, ON or OFF)")
|
|
set_property(CACHE CURL_${_dependency} PROPERTY STRINGS "AUTO" "ON" "OFF")
|
|
|
|
if(CURL_${_dependency} STREQUAL "AUTO")
|
|
find_package(${_dependency})
|
|
elseif(CURL_${_dependency})
|
|
find_package(${_dependency} REQUIRED)
|
|
endif()
|
|
endmacro()
|
|
|
|
# Convert the passed paths (or list of paths) to libpath linker options
|
|
# and add them to CMAKE_REQUIRED_LINK_OPTIONS.
|
|
macro(curl_required_libpaths)
|
|
set(_libpaths "${ARGN}")
|
|
foreach(_libpath IN LISTS _libpaths)
|
|
list(APPEND CMAKE_REQUIRED_LINK_OPTIONS "${CMAKE_LIBRARY_PATH_FLAG}${_libpath}")
|
|
endforeach()
|
|
endmacro()
|