mirror of
https://github.com/curl/curl.git
synced 2026-05-17 17:56:20 +03:00
b910122fe3
Add option to control whether to use `pkg-config` to detect
dependencies. Curl's CMake uses `pkg-config` by default for all targets
except for MSVC without vcpkg.
With the CMake option `-DCURL_USE_PKGCONFIG=ON` you can override it to
use `pkg-config` always.
If `pkg-config` is causing issues, e.g. in cross-builds or other cases,
`-DCURL_USE_PKGCONFIG=OFF` disables all use of `pkg-config`.
Also add it to `curl-config.cmake`. Not yet used, but will be once curl
starts referencing any curl-specific `Find*` module from this public
script.
Follow-up to 9dfdc6ff42 #14483
Closes #14504
71 lines
2.2 KiB
CMake
71 lines
2.2 KiB
CMake
#***************************************************************************
|
|
# _ _ ____ _
|
|
# Project ___| | | | _ \| |
|
|
# / __| | | | |_) | |
|
|
# | (__| |_| | _ <| |___
|
|
# \___|\___/|_| \_\_____|
|
|
#
|
|
# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
|
|
#
|
|
# This software is licensed as described in the file COPYING, which
|
|
# you should have received as part of this distribution. The terms
|
|
# are also available at https://curl.se/docs/copyright.html.
|
|
#
|
|
# You may opt to use, copy, modify, merge, publish, distribute and/or sell
|
|
# copies of the Software, and permit persons to whom the Software is
|
|
# furnished to do so, under the terms of the COPYING file.
|
|
#
|
|
# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
|
|
# KIND, either express or implied.
|
|
#
|
|
# SPDX-License-Identifier: curl
|
|
#
|
|
###########################################################################
|
|
# Find the wolfssl library
|
|
#
|
|
# Result Variables:
|
|
#
|
|
# WolfSSL_FOUND System has wolfssl
|
|
# WolfSSL_INCLUDE_DIRS The wolfssl include directories
|
|
# WolfSSL_LIBRARIES The wolfssl library names
|
|
# WolfSSL_VERSION Version of wolfssl
|
|
|
|
if(CURL_USE_PKGCONFIG)
|
|
find_package(PkgConfig QUIET)
|
|
pkg_search_module(PC_WOLFSSL QUIET "wolfssl")
|
|
endif()
|
|
|
|
find_path(WolfSSL_INCLUDE_DIR
|
|
NAMES "wolfssl/ssl.h"
|
|
HINTS ${PC_WOLFSSL_INCLUDE_DIRS}
|
|
)
|
|
|
|
find_library(WolfSSL_LIBRARY
|
|
NAMES "wolfssl"
|
|
HINTS ${PC_WOLFSSL_LIBRARY_DIRS}
|
|
)
|
|
|
|
if(WolfSSL_INCLUDE_DIR)
|
|
set(_version_regex "^#define[ \t]+LIBWOLFSSL_VERSION_STRING[ \t]+\"([^\"]+)\".*")
|
|
file(STRINGS "${WolfSSL_INCLUDE_DIR}/wolfssl/version.h"
|
|
WolfSSL_VERSION REGEX "${_version_regex}")
|
|
string(REGEX REPLACE "${_version_regex}" "\\1"
|
|
WolfSSL_VERSION "${WolfSSL_VERSION}")
|
|
unset(_version_regex)
|
|
endif()
|
|
|
|
include(FindPackageHandleStandardArgs)
|
|
find_package_handle_standard_args(WolfSSL
|
|
REQUIRED_VARS
|
|
WolfSSL_INCLUDE_DIR
|
|
WolfSSL_LIBRARY
|
|
VERSION_VAR
|
|
WolfSSL_VERSION
|
|
)
|
|
|
|
if(WolfSSL_FOUND)
|
|
set(WolfSSL_INCLUDE_DIRS ${WolfSSL_INCLUDE_DIR})
|
|
set(WolfSSL_LIBRARIES ${WolfSSL_LIBRARY})
|
|
endif()
|
|
|
|
mark_as_advanced(WolfSSL_INCLUDE_DIR WolfSSL_LIBRARY)
|